home *** CD-ROM | disk | FTP | other *** search
/ Super Shareware Collection / Super Shareware Collection.iso / info / rcntx323.zip / TRANSFER.EXE / BREAKIT.BAS < prev    next >
BASIC Source File  |  1991-11-24  |  2KB  |  69 lines
  1. 10 ON ERROR GOTO 480
  2. 20 D$(1)="-":D$(2)="\":D$(3)="|":D$(4)="/"
  3. 30 D=1
  4. 40 CLS
  5. 45 if command$="" then 50
  6. 46 f$=command$
  7. 47 print "Input file selected is ";F$
  8. 48 goto 60
  9. 50 INPUT "Enter name of input file";F$
  10. 60 OPEN "i",#1,F$
  11. 70 IF LOF(1)>250000 THEN GOTO 120
  12. 80 OPEN "o",#2,"index1.bat"
  13. 90 PRINT#2,"INDEX ";F$
  14. 100 CLOSE
  15. 110 SYSTEM
  16. 120 PRINT"            ╔════════════════════════════════════════════════╗"
  17. 130 PRINT"            ║     BREAKING UP INPUT FILE INTO WORKING        ║"
  18. 140 PRINT"            ║          FILES FOR RACONTEX INDEXER            ║"
  19. 150 PRINT"            ╚════════════════════════════════════════════════╝"
  20. 160 O$="P!"
  21. 170 I=I+1
  22. 180 O1$=O$+"."+RIGHT$(STR$(I),LEN(STR$(I))-1)
  23. 190 OPEN"o",#2,O1$
  24. 200 LOCATE 13,1
  25. 210 PRINT "                  ╔═════════════════════════╗"
  26. 220 PRINT "                  ║                         ║"
  27. 230 PRINT "                  ║                         ║"
  28. 240 PRINT "                  ║                         ║"
  29. 250 PRINT "                  ╚═════════════════════════╝"
  30. 260 LOCATE 14,21
  31. 270 PRINT "opening file ";O1$
  32. 280 LOCATE 8,1
  33. 290 PRINT "                             ╔═══╗"
  34. 300 PRINT "                             ║   ╣"
  35. 310 PRINT "                             ╚═══╝"
  36. 320 TAIL$=TAIL$+" "+O1$
  37. 330 LINE INPUT #1,L$
  38. 340 LOCATE 9,32:PRINT D$(D):D=D+1:IF D>4 THEN D=1
  39. 350 IF LEN(L$)>10 THEN IF RIGHT$(L$,10)="          " THEN L$=LEFT$(L$,LEN(L$)-10):GOTO 350
  40. 360 IF RIGHT$(L$,1)=" "THEN L$=LEFT$(L$,LEN(L$)-1):GOTO 360
  41. 370 CH=CH+LEN(L$)+2
  42. 380 LOCATE 16,21:PRINT "File Size = ";CH
  43. 390 PRINT#2,L$
  44. 400 IF EOF(1) THEN 430
  45. 410 IF CH>250000! THEN CLOSE 2 :CH=0:GOTO 170
  46. 420 GOTO 330
  47. 430 CLOSE
  48. 440 OPEN"o",#2,"index1.bat"
  49. 450 PRINT#2,"INDEX "+TAIL$
  50. 460 CLOSE
  51. 470 SYSTEM
  52. 480 REM error routine
  53. 490 IF ERL=60  THEN GOSUB 560:RESUME 60
  54. 500 PRINT"Please report to your system administrator error #";ERR;" at line ";ERL;" of BREAKIT"
  55. 510 PRINT "Press ENTER"
  56. 520 INPUT DUM$
  57. 530 OPEN"o",#2,"index1.bat"
  58. 540 CLOSE
  59. 550 SYSTEM
  60. 560 REM wrong file routine
  61. 570 CLS
  62. 580 PRINT "I can't open the file called ";F$
  63. 590 PRINT "What other file name should I try?"
  64. 600 PRINT "(enter NUL as a file name to abort this run)
  65. 610 INPUT F$
  66. 620 CLS
  67. 630 IF F$="NUL" OR F$="nul" GOTO 530
  68. 640 RETURN
  69.